# Maintainer: Alexander Epaneshnikov <alex19ep@archlinux.org>
# Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
# Maintainer: Frank Endres <frankendres@tuxfamily.org>
# https://raw.githubusercontent.com/archlinux/svntogit-community/packages/$name/trunk/PKGBUILD

pkgbase=speech-dispatcher
pkgname=(speech-dispatcher-pico libspeechd-pico)
pkgver=0.11.4
pkgrel=1
arch=('x86_64')
pkgdesc="High-level device independent layer for speech synthesis interface"
url='http://www.freebsoft.org/speechd'
license=('GPL2' 'FDL')
makedepends=('glib2' 'intltool' 'espeak-ng' 'libtool' 'python-pyxdg' 'dotconf' 'libpulse' 'libao' 'picotts')
conflicts=('speech-dispatcher' 'libspeechd')
source=("https://github.com/brailcom/speechd/releases/download/${pkgver}/speech-dispatcher-${pkgver}.tar.gz")
sha512sums=('d0ebe832e2586abdb1284be36f8427cfbbd94f1a2dead1b74526b151e9529f9e61679339274b73afab5f829d184337372ba0aad93d880c42d2a6a1bcb2b7afef')

build() {
  cd ${pkgbase}-${pkgver}

  ./configure --prefix=/usr --sysconfdir=/etc \
    --disable-static \
    --libexecdir=/usr/lib/speech-dispatcher/ \
    --with-ibmtts=no --with-kali=no --with-baratinoo=no \
    --with-voxin=no --without-flite \
    --with-pico
  make
}

package_speech-dispatcher-pico() {
  depends=("libspeechd-pico=$pkgver-$pkgrel" 'python-pyxdg' 'dotconf' 'libpulse' 'libao')
  optdepends=('festival: Speech output using Festival'
              'espeak-ng: Speech output using ESpeak-ng'
              'pulseaudio: PulseAudio support')
  backup=('etc/speech-dispatcher/clients/emacs.conf'
          'etc/speech-dispatcher/modules/dtk-generic.conf'
          'etc/speech-dispatcher/modules/epos-generic.conf'
          'etc/speech-dispatcher/modules/espeak-ng.conf'
          'etc/speech-dispatcher/modules/espeak-ng-mbrola.conf'
          'etc/speech-dispatcher/modules/espeak-ng-mbrola-generic.conf'
          'etc/speech-dispatcher/modules/festival.conf'
          'etc/speech-dispatcher/modules/llia_phon-generic.conf'
          'etc/speech-dispatcher/modules/mary-generic.conf'
          'etc/speech-dispatcher/modules/swift-generic.conf'
          'etc/speech-dispatcher/modules/pico.conf'
          'etc/speech-dispatcher/speechd.conf')
          
  cd ${pkgbase}-${pkgver}
  make DESTDIR="${pkgdir}" install

  rm "${pkgdir}/etc/speech-dispatcher/modules/cicero.conf"
  rm "${pkgdir}/etc/speech-dispatcher/modules/espeak.conf"
  rm "${pkgdir}/etc/speech-dispatcher/modules/espeak-mbrola-generic.conf"
  rm "${pkgdir}/etc/speech-dispatcher/modules/flite.conf"
  rm "${pkgdir}/usr/lib/speech-dispatcher/speech-dispatcher-modules/sd_cicero"

  sed -i 's|includedir=.*|includedir=${prefix}/include/speech-dispatcher|g' "${pkgdir}/usr/lib/pkgconfig/speech-dispatcher.pc"

  mkdir -p "${srcdir}"/libspeechd/usr/lib
  mv "${pkgdir}"/usr/include "${srcdir}"/libspeechd/usr
  mv "${pkgdir}"/usr/lib/libspeechd*so* "${srcdir}"/libspeechd/usr/lib
  mv "${pkgdir}/usr/lib/pkgconfig" "${srcdir}/libspeechd/usr/lib"
}

package_libspeechd-pico() {
  depends=('glib2' 'libtool')
  mkdir -p "${pkgdir}"/usr/lib

  mv "${srcdir}"/libspeechd/usr/include "${pkgdir}"/usr
  mv "${srcdir}"/libspeechd/usr/lib/* "${pkgdir}"/usr/lib
}
